Pasarela

attribute vec4 aBlock; /* x: column, y: row, z: height 0..1 (0 ground), w: world size */
    attribute vec2 aOffset; /* position inside the block, 0..1 */
    uniform float uRegime[8];
    uniform float uAmplify[8];
    uniform float uLength;
    uniform float uCanyon;
    varying vec4 vColor;
    
    uniform mat3 uR;
    uniform vec3 uCam;
    uniform vec2 uF;
    uniform float uPx;
    uniform float uDim;
    uniform float uTime;
    uniform float uReveal;

    const float NEAR = 12.0;
    const float FAR = 60000.0;
    const float FOG = 17000.0;
    const float FOCAL = 1150.0;

    vec4 project(vec3 world, out float dist) {
        vec3 v = uR * (world - uCam);
        dist = -v.z;
        float z = (dist * (FAR + NEAR) - 2.0 * FAR * NEAR) / (FAR - NEAR);
        return vec4(v.x * uF.x, -v.y * uF.y, z, dist);
    }

    /* Atmospheric perspective in the brand palette: light, lavender, purple, void. */
    vec3 ramp(float d) {
        vec3 light = vec3(0.937,0.933,0.922);
        vec3 lavender = vec3(0.922,0.843,0.922);
        vec3 purple = vec3(0.769,0.518,0.769);
        float t = d / FOG;
        return t < 0.3 ? mix(light, lavender, t / 0.3) : mix(lavender, purple, min(1.0, (t - 0.3) / 0.4));
    }

    float fogFade(float d) {
        return smoothstep(FOG, FOG * 0.18, d);
    }

    /* The scene appears as a scan going away from the viewer. */
    float revealed(float d) {
        return step(d, uReveal * FOG);
    }


    const float BLOCK = 625.0;
    const float WRAP = 20000.0;
    const float GROUND = 3600.0;
    const float LEVEL = 330.0;

    float hash(vec2 p) {
        vec3 q = fract(vec3(p.xyx) * 0.1031);
        q += dot(q, q.yzx + 33.33);
        return fract((q.x + q.y) * q.z);
    }

    float densityAt(float z) {
        float i = clamp(-z / uLength * 7.0, 0.0, 6.999);
        float a = floor(i);
        return mix(uRegime[int(a)], uRegime[int(a) + 1], i - a);
    }

    float amplifyAt(float z) {
        float i = clamp(-z / uLength * 7.0, 0.0, 6.999);
        float a = floor(i);
        return mix(uAmplify[int(a)], uAmplify[int(a) + 1], i - a);
    }

    /* Blocks are on or off and jump between powers of two, with no easing. */
    float level(vec2 block, float density) {
        if (abs(block.x) * BLOCK < uCanyon) return 0.0;
        float r = hash(block * 0.731 + 3.1);
        float period = 7.0 + r * 26.0;
        float phase = floor(uTime / period + r * 31.0);
        float s = hash(block + vec2(phase * 0.37, phase * 0.11));
        if (s >= density) return 0.0;
        float q = s / density;
        return q < 0.5 ? 1.0 : q < 0.78 ? 2.0 : q < 0.93 ? 4.0 : 8.0;
    }

    void main() {
        float zRel = mod(uCam.z - aBlock.y * BLOCK, WRAP);
        float zBlock = uCam.z - zRel;
        vec2 block = vec2(aBlock.x, floor(zBlock / BLOCK + 0.5));

        float lv = level(block, densityAt(zBlock));
        float height = lv * LEVEL * amplifyAt(zBlock);
        float isOn = step(0.5, lv);

        vec3 world = vec3(
            (block.x - 0.5 + aOffset.x * 0.92) * BLOCK,
            GROUND - height * aBlock.z,
            zBlock - (aOffset.y * 0.92) * BLOCK
        );

        float d;
        gl_Position = project(world, d);

        float isGround = 1.0 - step(0.001, aBlock.z);
        float isTop = step(0.999, aBlock.z);
        float strength = isGround * 0.16 + (1.0 - isGround) * isOn * mix(0.42, 0.85, isTop);

        vec3 colour = ramp(d * 1.25);
        if (hash(block * 1.7) > 0.982) colour = vec3(1,0.427,0.682);

        vColor = vec4(colour, strength * fogFade(d) * smoothstep(60.0, 500.0, d) * revealed(d) * uDim);
        gl_PointSize = max(1.0, aBlock.w * uPx * FOCAL / max(d, 1.0));
    }